XML.lastChild

Доступность

Flash Player 5.

Синтаксис

my_xml.lastChild:XMLNode

Описание

Свойство, доступное только для чтения; объект XMLNode, указывающий на последний узел в списке дочерних узлов для данного объекта. Свойство XML.lastChild равно null, если у узла нет дочерних узлов. Это свойство не может быть использовано для управления дочерними узлами; используйте для этого методы appendChild(), insertBefore() и removeNode().

Пример

В примере ниже свойство XML.lastChild используется для обхода дочерних узлов XML узла, с последнего дочернего узла к первому:

// Создаем новый XML документ
var doc:XML = new XML();

// Создаем корневой узел
var rootNode:XMLNode = doc.createElement("rootNode");

// Создаем три дочерних узла
var oldest:XMLNode = doc.createElement("oldest");
var middle:XMLNode = doc.createElement("middle");
var youngest:XMLNode = doc.createElement("youngest");

// Добавляем узел rootNode как корневой узел в дерево XML документа
doc.appendChild(rootNode);

// Делаем каждый созданный дочерний узел дочерним узлом узла rootNode
rootNode.appendChild(oldest);
rootNode.appendChild(middle);
rootNode.appendChild(youngest);

// Используя lastChild проходим по дочерним узлам rootNode
for (var aNode:XMLNode = rootNode.lastChild; aNode != null; aNode = aNode.previousSibling) {
  trace(aNode);
}

/* 
Выведет:
<youngest />
<middle />
<oldest />
*/

В примере ниже создается новый XML документ и свойство XML.lastChild используется при обходе дочерних узлов корневого элемента:

// Создаем новый XML документ
var doc:XML = new XML("<rootNode><oldest /><middle /><youngest /></rootNode>");

var rootNode:XMLNode = doc.firstChild;

// Используя lastChild проходим по дочерним узлам rootNode
for (var aNode:XMLNode = rootNode.lastChild; aNode != null; aNode=aNode.previousSibling) {
  trace(aNode);
}
/*
Выведет:
<youngest />
<middle />
<oldest />

См. также

XML.appendChild(), XML.insertBefore(), XML.removeNode(), Класс XMLNode

Смотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление